Cara Membuat Teks Terbilang Otomatis di Excel

Rumus terbilang saat ini memang belum ada pada fitur excel, untuk itu harus membuat secara manual atau bisa juga menggunakan aplikasi ke tiga dengan memanfaatkan fitur add-ins, namun untuk fitur add-ins terkadang mempengaruhi kinerja Microsoft Excel pada saat startup.

Dengan demikian, teman-teman sekalian tidak perlu khawatir sebab ada solusi untuk mengatasi itu semua, namun solusi ini khusus teks terbilang pada rupiah, misalnya: Seribu Rupiah, Dua Ribu Rupiah dan seterusnya. Fitur memanfaatkan VBA, apat itu VBA?, VBA adalah bahasa pemrograman berbasis objek yang memungkinkan pengguna untuk menulis kode yang akan dijalankan dalam aplikasi Office.

Berikut langkah-langkahnya:

1.     Buka Microsoft Excel;

2.     Kemudian pilih menu Developer;

3.     Setelah itu pilih Visual Basic;

4.     Selanjutnya pilih menu Insert;

5.     Kemudian pilih Module dan copy kode berwarna biru berikut dan paste pada kotak dialog Mudule tersebut: 

 Function Terbilang(ByVal angka As Double) As String
    Dim satuan As Variant
    satuan = Array("", "Satu", "Dua", "Tiga", "Empat", "Lima", "Enam", "Tujuh", "Delapan", "Sembilan")
    
    Dim tingkat As Variant
    tingkat = Array("", "Ribu", "Juta", "Miliar", "Triliun")
    
    Dim hasil As String
    Dim isMinus As Boolean
    Dim i As Integer
    Dim groupVal As Integer
    Dim temp As String
    
    If angka = 0 Then
        Terbilang = "Nol Rupiah"
        Exit Function
    End If
    
    If angka < 0 Then
        isMinus = True
        angka = Abs(angka)
    End If
    
    i = 0
    Do While angka > 0
        groupVal = angka Mod 1000
        If groupVal <> 0 Then
            temp = ""
            
            Dim ratus As Integer
            Dim puluh As Integer
            Dim satu As Integer
            Dim duaDigit As Integer
            
            ratus = Int(groupVal / 100)
            duaDigit = groupVal Mod 100
            puluh = Int(duaDigit / 10)
            satu = duaDigit Mod 10
            
            ' Ratusan
            If ratus > 0 Then
                If ratus = 1 Then
                    temp = "Seratus "
                Else
                    temp = satuan(ratus) & " Ratus "
                End If
            End If
            
            ' Puluhan dan satuan
            If duaDigit > 0 Then
                If puluh = 1 Then
                    If satu = 0 Then
                        temp = temp & "Sepuluh "
                    ElseIf satu = 1 Then
                        temp = temp & "Sebelas "
                    Else
                        temp = temp & satuan(satu) & " Belas "
                    End If
                Else
                    If puluh > 1 Then
                        temp = temp & satuan(puluh) & " Puluh "
                    End If
                    If satu > 0 Then
                        temp = temp & satuan(satu) & " "
                    End If
                End If
            End If
            
            ' Penanganan khusus Seribu
            If i = 1 And groupVal = 1 Then
                temp = "Seribu "
            End If
            
            hasil = temp & tingkat(i) & " " & hasil
        End If
        angka = Int(angka / 1000)
        i = i + 1
    Loop

    hasil = Application.WorksheetFunction.Trim(hasil) & " Rupiah"
    If isMinus Then
        hasil = "Minus " & hasil
    End If
    
    Terbilang = hasil
End Function

6.     Kemudian tutup kembali Visual Basic;

7.     Selesai, kini teman-teman sudah bisa menggunakan fitur terbilang rupiah secara otomati.

Selamat beraktifitas dan tetap semangat dalam bertugas teman-teman.